前回(2020/10/04)は近似式を用いて１価の弱酸のpHを求めました。エクセルを用いれば、近似式を用いなくてもpHのかなり厳密な近似解を求めることができ、近似式の妥当性の確認も不要となり作業の手間が省けます。エクセルを用いると言ってもやり方はいろいろです。今回は「二分法」による方法を紹介します。
＜「二分法」による解＞
「Ca=0.01 mol/Lの酢酸(pKa=4.75)のpHを求める」ことを例題として「二分法」のやり方を説明します。
Ka = [H][A]/[HA] …(a)
Kw = [H][OH] …(b)
Ca = [A]+[HA] …(c) (物質収支式)
Q = [H]－[OH]－[A] = 0 …(d) (電荷収支式)
「二分法」の実施方針は次の通りです。
(1) Q = [H]－[OH]－[A]を[H]のみの関数(Q(H))として表す。
(2) このために、[OH]について、(b)式から [OH]=Kw/[H]とする。
(3) [A]について、(a)式と(c)式から [A]= Ca/(1＋[H]/Ka)(*1)とする。
(*1) (a)式より、[HA] = [H][A]/Ka
この式を(c)式に代入して、Ca= [A]＋[HA] = [A](1＋[H]/Ka)
α = 1＋[H]/Kaとすると、Ca = [A]α ∴[A]= Ca/α
(4) Q([H]) = [H]－Kw/[H]－Ca/(1＋[H]/Ka)
(5) 二分法の表を作り、Q([H]) =0と近似できるまで二分法の操作を繰り返す。
「二分法」表の作成方法(図-1を参照)
① pKa,pKw, Caの値(定数)をD3～D5のセルに入れる。
② Ka, Kwを計算する。
・D6 =10^-D3
・D7 =10^-D4
③ pHの初期値pHa0, pHm0, pHb0をC11～E11のセルに入れる。
・C11 =0
・D11 =7
・E11 =14
④ 二分法のロジック式をC12～E12のセルに入れる。
・C12 =IF(F11<0,C11,D11)
・D12 =(C12+E12)/2
・E12 =IF(C12=D11,E11,D11)
⑤ 二分法のロジック式をコピーする。
・C12：E12を選択し、C42：E42までコピーする（ポインターを＋にしてドラッグ）。
⑥ 初期値について濃度に関する計算式を入れる。（F11～K11）
・F11 =G11-H11-J11 …(Q=[H]-[OH]-[A])
・G11 =10^-D11 …([H]=10^-pHm)
・H11 =$D$7/G11 …([OH]=Kw/[H])
・I11 =1+G11/$D$6 …(α=1+[H]/Ka)
・J11 =$D$5/I11 …([A]=Ca/α)
・K11 =G11*J11/$D$6 …([HA]=[H][A]/Ka)
⑦ 濃度の計算式をコピーする。
・F11：K11を選択し、F42：K42までコピーする。
⑧ pHの値をコピーする。
・D8 =D42 …(これが求めるpH)
結 果
作成した二分法の表を図-１に、計算式を図-２に示します。
図-１(二分法)
図-２(計算式)
＜Ka, CaとpHの関係＞
酸解離定数Kaおよび全濃度Caを様々に変化させたときのpHの値を、二分法とデータテーブルを用いて求めます。
二分法の表の作成
二分法の表の作成は上記の例と同様です。二分法の表を図-３(左側)に示します。
図-３
データテーブルの作成
二分法の表とデータテーブルを組み合わせることにより、Ka, Caを変化させたときのpHの値を求めます。
(1) logCaの変化値を入れる。
・N列目にlogCa=0～-14.0まで0.1きざみでいれる。（N7:N147）
(2) pKaの変化値を入れる。
・6行目にlogKa=14～1まで1.0きざみでいれる。（O6:AB6）
(3) 二分法の表で求めたlogCa=0, pKa=14のときのpHの値(D39)をN6にコピーする。
・N6 =D39
(4) データテーブルの範囲を指定する。（N6:AB147）
(5) データテーブルを作成する。
・メニューバー：「データ」
・ツールバー：「What-If分析」⇒「データテーブル」⇒「データテーブル」ダイアログが出る(下図）⇒「行の代入セル」に”H4”を指定⇒「列の代入セル」に”D4”を指定⇒「OK」
これで、データテーブルが完成です図-３(右側)。
Ka, CaとpHの関係図
logKaを1～14, logCaを0～－14と変化させたときのpHの変化を図-４に示します(この図はFlood図と呼ばれます)。なお、図中には[H]=√(CaKa)の近似式(2020/10/04)が成立する範囲も示しました。
図-４(Flood図)
コメント