グリシンの滴定曲線(二分法) : 滴定曲線、溶解度などーエクセルを用いて

アミノ酸の１種であるグリシン(H₂N･CH₂･COOH)は分子内にアミノ基とカルボキシ基を１個ずつ持つモノアミノ・モノカルボン酸です。グリシン塩酸塩を水酸化ナトリウムで滴定する場合について、二分法を用いて理論的滴定曲線を作成します。　　　

濃度C_goのグリシン塩酸塩(H₂G⁺Cl^-), V mLを濃度C_boのNaOHで滴定します。滴定剤の添加量をT mLとし、グリシンの酸解離定数をK₁, K₂, 水のイオン積をK_wとします。　　　

<＜関係式＞>　
H₂G⁺Cl^- → H₂G⁺ ＋ Cl^-
H₂G⁺ ⇆ H⁺ ＋ HG　 K₁ = [H][HG]/[H₂G]
HG ⇆ H⁺ ＋ G^-　 K₂ = [H][G]/[HG]

H₂O ⇆ H⁺ ＋ OH^-　 K_w = [H][OH]
NaOH → Na⁺ ＋ OH^-　　　

物質バランスから、被滴定溶液中のグリシン, Cl^-, Na⁺濃度をそれぞれC_g, C_c, C_bとすると、

グリシンに関して、
C_g = C_goV/(V+T)
　 = [G]+[HG]+[H₂G]
　 = [G](1+[H]/K₂+[H]²/(K₂K₁)) = [G]α
ここで、α= 1+[H]/K₂+[H]²/(K₂K₁)
また、Cl^-, Na⁺に関して、
C_c = C_g = [Cl]
C_b = C_boT/(V+T)　　　

したがって、被滴定溶液中の化学種濃度は、
[H] = 10^－pH
[OH] = K_w/[H]
[G] = C_g/α
[HG] = [H][G]/K₂
[H₂G] = [H][HG]/K₁
[Cl] = C_g
[Na] = C_b　　　

また、電荷バランスから、
Q = [H]－[OH]－[G]＋[H₂G]－[Cl]＋[Na] = 0　　　

<＜エクセルシート>＞
C_go=0.1 mol/Lのグリシン塩酸塩 V=10 mLをC_bo=0.1 mol/LのNaOHで滴定し、滴下量をT mLとします。また、pK₁=2.35, pK₂=9.78, pK_w=14.00とします。
＜条件表＞
(1)　pK₁, pK₂, pK_wの値をE4, E5, E6に入れ、C_ao, V, C_boの値をD7, D8, D9に入れる。
(2)　T(D10)に"0"を入れる。
(3)　K₁, K₂, K_w, V+T, C_a, C_bの計算式をD4, D5, D6, D11, D12, D13に入れる。　　・
　　・D4=10^-E4　{K₁=10^-pK₁}
　　・D5=10^-E5　{K₂=10^-pK₂}
　　・D6=10^-E6　{K_w=10^-pK_w}
　　・D11=D8+D10　{V+T}
　　・D12=D7*D8/D11　{C_g=C_goV/(V+T)}
　　・D13=D9*D10/D11　{C_b = C_boT/(V+T)]

＜二分法表＞
(4)　初回(18行目)：　pHの初期値a₀, b₀をC18, E18に入れ、m₀の計算式をD18に入れる。
　　・C18=0
　　・D18=(C18+E18)/2　{m₀=(a₀+b₀)/2}
　　・E18=14
(5)　初期値に対して、濃度に関する計算式をF18～L18に入れる。
　　・F18=G18-H18-J18+L18-M18+N18　{Q=[H]-[OH]-[G]+[H2G]-[Cl]+[Na]}
　　・G18=10^(-D18)　{[H]=10^(-pH)}
　　・H18=$D$6/G18　{[OH]=K_w/[H]}
　　・I18=1+G18/$D$5+G18^2/($D$5*$D$4)　{α=1+[H]/K₂+[H]^{^2}/(K₂K₁)}
　　・J18=$D$12/I18　{[G]=C_a/α}
　　・K18=G18*J18/$D$5　{[HG]=[H][G]/K₂}
　　・L18=G18*K18/$D$4　{[H₂G]=[H][HG]/K₁}
　　・M18=$D$12　{[Cl]=C_b}
　　・N18=$D$13　{[Na]=C_b}　　　

(6)　繰り返し１回目(19行目)：　二分法のロジック式をC19～E19に入れ、濃度に関しては初回の計算式をコピーする。
　　・C19=IF(F18<0,C18,D18)　{a₁=IF(Q₀<0, a₀, m₀)}
　　・D19=(C19+E19)/2　{m₁=(a₁+b₁)/2}
　　・E19=IF(F18<0,D18,E18)　{b₁=IF(Q₀<0, m₀, b₀)}
(7)　範囲(F18:N18)を選択し、F19：N19までコピーする。
　　（範囲の右下隅の■を⊞にして19行目までドラッグ）
(8)　繰り返し2～30回目：　範囲C19:N19を選択し、C48：N48までコピーする。
　　（範囲の右下隅の■を⊞にして48行目までドラッグ）
(9)　D48が求めるpHである。求めたpHの値を条件表にコピーする。
　　・D14=D48　　　

これで、条件表、二分法表が完成です(図-1のC列～N列)。　　　

＜データテーブルの作成＞
(10)　P列に滴定量T mLの値を0.1 mLきざみで0～40 mLまでいれる。
　　・P5に"0", P6に"0.1"を入れる。
　　・範囲(P5:P6)を選択し、範囲右下隅の■を⊞にして405行目までドラッグする。
(11) 二分法表(T=0)のpH(D14)をQ5にコピーする。
　　・Q5=D14
(12) データテーブルの作成範囲(P5:Q405)を指定する。
(13) データテーブルを作成する。
　　・メニューバー：「データ」
　　・ツールバー：「What-If分析」⇒「データテーブル」⇒ダイアログボックス　⇒「列の代入セル」に”D10”(滴下量T)を指定する(「行の代入セル」は空欄のまま) ⇒「OK」　　　