前回(2023-11-26)は「近似法」によるポリプロトン酸塩基の滴定曲線の描き方について説明しましたが、今回は、「二分法」について説明します。近似法では開始前、当量点およびその前後で別々の近似式を用いる必要があり煩雑ですが、二分法を用いると、任意の条件で滴定曲線を一度に描くことができ、また条件の変更も容易です。　　　

<<関係式>>
C_ao mol/Lのポリプロトン酸(H_mA), V mLをC_bo mol/Lの強塩基(NaOH), T mLで滴定する場合を考えます。このときの関係式は次の通りです。なお、以下の滴定に関する考察においてイオン強度の影響は無視します。
平衡定数：
K₁ = [H][H_m-1A]/[H_mA]
K₂ = [H][H_m-2A]/[H_m-1A]
…
K_m-1 = [H][HA]/[H₂A]
K_m = [H][A]/[HA]
K_w = [H][OH]　　　

物質バランス：
C_a = C_aoV/(V＋T) = [A]＋[HA]＋…＋[H_mA]
C_b = C_boT/(V＋T) = [Na]　　　

電荷バランス：
Q = [H]＋[Na]－([OH]＋m[A]＋(m-1)[HA]＋…＋[H_m-1A]) = 0　　　

被滴定溶液の化学種濃度：
[H] = 10^{^－pH}
[OH] = K_w/[H]
[A] = C_a/α = C_a/(1＋[H]/K_m＋[H]^{^2}/(K_m K_m-1)＋…＋[H]^{^m}/(K_m K_m-1… K₁))
[HA] = [H][A]/K_m
[H₂A] = [H][HA]/K_m-1
　……　
[H_mA] = [H][H_m-1A]/K₁
[Na] = C_b　　　

<<二分法の操作>>
二分法の原理についてはここ(2023-04-30)をご覧ください。
C_ao mol/Lのジプロトン酸(H₂A), V mLをC_bo mol/Lの強塩基(NaOH), T mLで滴定する場合を例としてエクセルを用いた二分法のやり方を説明します。作成したシートの例を図-１に示します。　　　

図-１

計算式　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　

　　D6=10^-D3
　　D7=10^-D4
　　D8=10^-D5
　　E18=F18-G18+H18-2*I18-J18 F18=10^-C18
　　G18=$D$8/F18
　　H18=$D$11*$D$12/($D$10+$D$12)
　　I18=$D$9*$D$10/($D$10+$D$12)/(1+F18/$D$7+F18^2/($D$7*$D$6))
　　J18=F18*I18/$D$7
　　K18=F18*J18/$D$6
　　B19=IF(E18<0,B18,C18)
　　C19=(B19+D19)/2
　　D19=IF(B19=C18,D18,C18)　　　

このシートに添って説明します。
＜条件表＞
条件表に定数値pK₁, pK₂, pK_w, C_ao, V, C_bo, T(=0)を入力し、K₁, K₂, K_wの計算式を入れる。
　K₁=10^{^-pK1}
　K₂=10^{^-pK2}
　K_w=10^{^-pKw}　　　

＜二分法表＞
二分法の操作においてQ(m)の正負の判断および対応についてはIF関数を用います。
・初期値の入力と、m₀, 化学種濃度およびQ(m₀)値の計算(n=0行目)
(1)　Q(a₀)＞0となるような初期値a₀を入れる。
　a₀=－1
(2)　Q(b₀)＜0となるような初期値b₀を入れる。
　b₀=15
(3)　a₀, b₀の中点、m₀の計算式を入れる。
　m₀=(a₀+b₀)/2
(4)　m₀に対応するQ(m₀)および化学種濃度の計算式を入れる。
　Q(m₀) = [H]＋[Na]－[OH]－２[A]－[HA]
　[H]=10^-m₀
　[OH]=K_w/[H]
　[Na]=C_boT/(V+T)
　[A]=C_aoV/(V+T)/(1+[H]/K₂+[H]^{^2}/(K₂K₁))
　[HA]=[H][A]/K₂
　[H₂A]=[H][HA]/K₁　　　　

・二分法操作１回目(n=1行目)
(5)　Q(m₀)＜0ならば、a₁=a₀とする。そうでなければ、a₁=m₀とする。
　a₁=IF(Q(m₀)<0, a₀, m₀)
(6)　a₁=m₀(つまりQ(m₀)>=0)ならば、b₁=b₀とする。そうでなければ、b₁=m₀とする。
　b₁=IF(a₁=m₀, b₀, m₀)　(または、b₁=IF(Q(m₀)<0, m₀, b₀))
(7)　a₁, b₁の中点m₁の計算式を入れる。
　m₁=(a₁+b₁)/2
(8)　m₁に対応するQ(m₁)および化学種濃度の計算式を入れる。
　n=0行目のQ(m₀)および化学種濃度の計算式をn=1行目にコピーする。　　　

・二分法操作２回目以降(n=2～30行目)
(9)　n=2～30行目に計算式を入れる。
　操作１回目(n=1行目)の計算式をすべてn=2～30行目までコピーする。
(10)　m₃₀が求めるpHである。　　　

＜データテーブル＞
K₁, K₂, K_w, C_ao, C_bo, Vはすべて定数です。したがって滴下量Tを与えれば二分法によりpHを求めることができます。Tを少しずつ変化させて、それに対応するpHを求めるためには、エクセルのデータテーブル機能を用います。
(1)　空白の列にTの値を0.2 mLきざみでT=0～40 mLまで入れる。
(2)　その隣列のT=0のセルにm₃₀のセルの計算式をコピーする。
(3)　データテーブルの作成範囲を指定する(見出しは指定しない！)。
(4)　データテーブルを作成する。
・メニューバー：「データ」⇒ ツールバー：「What-If分析」⇒「データテーブル」⇒ダイアログボックスが開く ⇒「列の代入セル」に"滴下量T"のセルを指定する(「行の代入セル」は空欄のまま) ⇒「OK」
これで、データテーブルに各Tの値に対するpHの値が出力される。　　　

＜滴定曲線＞
データテーブルを基にポリプロトン酸(H_mA)の滴定曲線を描きます。
(1)　見出しを含め散布図作成の範囲を指定する。
(2)　散布図を作成する。
・メニューバー：「挿入」⇒ ツールバー：「グラフ」⇒「散布図」⇒「散布図(平滑線)」⇒「OK」　　　

散布図は目的に応じて適当にカスタマイズして滴定曲線を作成します。0.1 mol/Lマレイン酸(pK₁=1.92, pK₂=6.27) 10 mLを0.1 mol/L NaOHで滴定した場合の滴定曲線を図-２に示します。　　　

図-２

<<様々な酸塩基の滴定曲線>>
二分法を用いると、様々な酸塩基の滴定曲線を描くことができます。リン酸をNaOHで滴定した場合、また炭酸ナトリウムをHClで滴定した場合を示します。
＜リン酸の滴定曲線＞
0.1 mol/Lリン酸H₃PO₄(pK₁=2.15, pK₂=7.20, pK₃=12.38) 10 mLを0.1 mol/L NaOHで滴定した場合の滴定曲線を二分法で描きます。関係式は次の通りです。
平衡定数：
K₁ = [H][H₂PO₄]/[H₃PO₄]
K₂ = [H][HPO₄]/[H₂PO₄]
K₃ = [H][PO₄]/[HPO₄]
K_w = [H][OH]
物質バランス：
C_a = C_aoV/(V＋T) = [PO₄]＋[HPO₄]＋[H₂PO₄]＋[H₃PO₄]
C_b = C_boT/(V＋T) = [Na]
電荷バランス：
Q = [H]＋[Na]－([OH]＋3[PO₄]＋2[HPO₄]＋[H₂PO₄]) = 0
被滴定溶液の化学種濃度：
[H] = 10^{^－pH}
[OH] = K_w/[H]
[PO₄] = C_a/α = C_a/(1＋[H]/K₃＋[H]^{^2}/(K₃K₂)＋[H]^{^3}/(K₃ K₂K₁))
[HPO₄] = [H][PO₄]/K₃
[H₂PO₄] = [H][HPO₄]/K₂
[H₃PO₄] = [H][PO₄]/K₁
[Na] = C_b　　　

作成したエクセルシートおよび滴定曲線を図-３に示します。第３当量点は明確なジャンプを示しません。　　　

図-３

＜炭酸ナトリウムの滴定曲線＞
0.1 mol/L炭酸ナトリウムNa₂CO₃(pK₁=6.35, pK₂=10.33) 10 mLを0.1 mol/L HClで滴定した場合の滴定曲線を二分法で描きます。関係式は次の通りです。
平衡定数：
K₁ = [H][HCO₃]/[H₂CO₃]
K₂ = [H][CO₃]/[HCO₃]
K_w = [H][OH]
物質バランス：
C_b = C_boV/(V＋T) = [CO₃]＋[HCO₃]＋[H₂CO₃]
2C_b = 2C_boV/(V＋T) = [Na]
C_a = C_aoT/(V＋T) = [Cl]
電荷バランス：
Q = [H]＋[Na]－([OH]＋[Cl]＋2[CO₃]＋[HCO₃]) = 0
被滴定溶液の化学種濃度：
[H] = 10^{^－pH}
[OH] = K_w/[H]
[CO₃] = C_b/α = C_a/(1＋[H]/K₂＋[H]^{^2}/(K₂K₁))
[HCO₃] = [H][CO₃]/K₂
[H₂CO₃] = [H][HCO₃]/K₁
[Na] = 2C_b
[Cl] = C_a　　　

作成したエクセルシートおよび滴定曲線を図-４に示します。　　　

図-４